自然與生活科技

代碼: 選擇全部

OCR1A = (目標計數時間 * 計數頻率) - 1
OCR1A = (1秒 * 62500) - 1 = 62499

代碼: 選擇全部

const long interval = 1000;  // interval time in milliseconds for the clock to update
long previousMillis = 0;    // will store last time the timer was updated
volatile boolean timeToCount = false;

void setup() {
  // 設置Timer1以CTC模式運行
  TCCR1A = 0;               // 設置計時器控制寄存器A [WGM12: CTC模式，定義波形產生模式]
  TCCR1B |= (1 << WGM12);   // 設置計時器控制寄存器B [設置WGM12位]
  TCCR1B |= (1 << CS12);    // 設置預分頻為256
  OCR1A = 62499;            // 設置計時器頂值為62500 - 1
    
  // 啓用比較中斷
  TIMSK1 |= (1 << OCIE1A);
  
  // 初始化序列埠
  Serial.begin(9600);
  
  //全局中斷
  sei();
}

void loop() {
  if(timeToCount){
    timeToCount = false;

    unsigned long currentMillis = millis();
    if (currentMillis - previousMillis >= interval) {
      previousMillis = currentMillis;
      Serial.println("1 second has passed");
    }
  }
}

ISR(TIMER1_COMPA_vect) {
  timeToCount = true;
}

代碼: 選擇全部

/* Timer1(16bits)最大值65535計時1秒,將針腳13LED反相 
石英振盪=16MHz + 設定CTC模式(Clear Timer on Compare Match)
TCCR1A要設-->WGM11=0 WGM10=0
TCCR1B要設-->WGM13=0 WGM12=1 (除頻256-->CS12=1 CS11=0 CS10=0)
<註>1.CS12=1 CS11=0 CS10=0 查表:除256
<註>2.使用除頻器除256,16M/256=62500Hz
<註>3.OCR1A=(目標時間*計數頻率)-1-->OCR1A=(1秒*62500)-1=62499次
<註>4.比較器中斷法,數值不可以超過65535,否則要換方法
<註>5.比較中斷62499次,才可以得到1秒!
*/
#include<avr/io.h>
#include<avr/interrupt.h>
#define PINLED 13 //內建第13腳位的LED燈
//volatile uint16_t cntInt=0;//中斷次數值(volatile的宣告方式適合中斷後,計數不會被更改)
volatile bool stateLED=LOW;//LED目前為(滅)
uint32_t preTime,curTime;//前次時間,目前時間
volatile bool flag1s=false;//旗熛判斷(是否達1秒)
//----------Timer1設為CTC模式比較中斷模式 ------------
void init_timer1_CTC(){
 // 設置Timer1以CTC模式運行
 TCCR1A=TCCR1A &(~(1<<WGM11))&(~(1<<WGM10));//設為0
 TCCR1B=TCCR1B &(~(1<<WGM13));//設為0
 TCCR1B=TCCR1B |((1<<WGM12));//設為1
//暫存器TCCR1B(CS12=1,CS11=0,CS10=0)設置預分頻為256
 TCCR1B=TCCR1B &(~(1<<CS11))&(~(1<<CS10));//
 TCCR1B=TCCR1B |((1<<CS12));// 
 OCR1A = 62499;   // 設置比較值為62500 - 1
 TIMSK1 |= (1 << OCIE1A);//啓用比較中斷
 sei();//啟動中斷功能
}
//---------設定arduino 接腳輸出------------------------
void init_pin(){
  pinMode(PINLED, OUTPUT);//設為輸出
  digitalWrite(PINLED,stateLED);
}
//----------------------------------------------------
void setup() {
  Serial.begin(9600);//序列傳輸
  init_pin();//呼叫 arduino接腳輸出設定
  init_timer1_CTC();//呼叫timer1設為CTC的函式
  curTime=micros();//紀錄目前時間
}

void loop() {
  if(flag1s){ //旗標等於1秒時
    preTime=curTime;//目前覆蓋於前次
    curTime=micros();//現在歸零
    Serial.println(curTime-preTime);//輸出所需的1秒鐘,誤差為多少
    flag1s=false;//等待下一個1秒的旗標
  }

}
//-------以下為比較中斷服務函式----------------------------
//計數器1
ISR(TIMER1_COMPA_vect){
    stateLED=!stateLED;//1秒後反相輸出
    digitalWrite(PINLED,stateLED);
    flag1s=true;//設定1秒旗標,供主迴圈使用
}